/*  ReactionTime1.sas  */
title "Ana's Perception Study: Reaction Time";
title2 'Multivariate approach to repeated measures';


/* Read data directly from Excel spreadsheet */
proc import datafile="/folders/myfolders/2453f15/RT_Medians.xls" 
            out=rtime1 dbms=xls replace;
            getnames=yes;

proc print; 
run; 

data rtime2;
     set rtime1;
     label NCQ	= 'No Context Question'
           NCE	= 'No Context Exclamation'
           NCS	= 'No Context Statement'
           LCQ	= 'Low Context Question'
           LCE	= 'Low Context Exclamation'
           LCS	= 'Low Context Statement'
           CQ	= 'Context Question'
           CE	= 'Context Exclamation'
           CS   = 'Context Statement';
     NCmean = (NCQ+NCE+NCS)/3;
     LCmean = (LCQ+LCE+LCS)/3;
     Cmean = (CQ+CE+CS)/3;
     Questmean3 = (NCQ+LCQ+CQ)/3;
     Exclamean3 = (NCE+LCE+CE)/3;
     Statemean3 = (NCS+LCS+CS)/3;
     Questmean2 = (NCQ+LCQ)/2;
     Exclamean2 = (NCE+LCE)/2;
     Statemean2 = (NCS+LCS)/2;
           
proc means;
     class Language;
     var NCQ -- Statemean2;
     
proc glm;
     title3 'All Three Tasks';
     class Language;
     model NCQ	NCE	NCS	LCQ	LCE	LCS	CQ	CE	CS = Language;
     repeated Task 3, SentenceType 3 / short summary nouni mean;
/* Factor on the right changes fastest (like numbers) */

/* As Ana says, Context Task is a different animal. */

proc glm;
     title3 'Two levels of task: No Context and Low Context';
     class Language;
     model NCQ	NCE	NCS	LCQ	LCE	LCS = Language;
     repeated Task 2, SentenceType 3 / short summary nouni mean;

proc glm;
     title3 'Just the Context Task: Language by Sentence Type';
     class Language;
     model CQ	CE	CS = Language;
     repeated SentenceType 3 / short summary nouni mean;