Regression with observed variables using SAS proc calis

/**************************** SATcalisReg.sas ****************************/
title 'Open SAT Data: Fit a regression model with proc calis';
title2 'Jerry Brunner:  Student Number 999999999';

data PennState;
     infile '/folders/myfolders/431s17/openSAT.data.txt' firstobs=2;  
     input id verbal math gpa;             /* Skipping the header */

ods graphics off; /* Suppress regression plots */
proc reg;
     title3 'Proc reg for comparison';     	 
     model gpa = verbal math;

proc calis vardef=n nostand; /* Use n in the denominator for pure MLEs
                                Suppress standardized output */
	 title3 'Surface regression with proc calis';
     var verbal math gpa;       /* Declare observed variables */
     lineqs                     /* Give model equation(s) */
        gpa = beta0*Intercept + beta1*verbal + beta2*math + epsilon;
     variance                   /* Declare variance parameters */
        verbal = phi11,
        math = phi22,
        epsilon = sigmasq;
     cov                        /* Declare non-zero covariance parameters */
        verbal math = phi12;  
     mean                       /* Declare non-zero mean parameters */
        verbal = mu1, math = mu2;
run; 
/* The final run statement is not strictly necessary in SAS Studio. */

Output

Vocabulary used by proc calis:

Latent variable

A random variable that cannot be directly observed, and also is not an error term.

Manifest variable

An observable variable. An actual data set contains only values of the manifest variables.

Exogenous variable

A purely explanatory variable that is not an error term. In the regression-like equations of a structural equation model, the exogenous variabes are ones that appear only on the right side of at least one equals sign, and never on the left side in any equation.

Endogenous variable

A variable that appears on the left side of at least one equals sign. Endogenous variables depend on the exogenous varables, and possibly other endogenous variables. Think of an arrow from an exogenous variable to an endogenous variable. The end of the arrow is pointing at the endogenous variable.