Fitting a model when the parameters are not identifiable

• Summary: When the parameters of a model are not identifiable and you fit it anyway, there can be nasty numerical symptoms. Watch out for any reference to the Moore-Penrose inverse, a generalized inverse used by SAS in the numerical search when the determinant of Σ(θ) gets too close to zero. SAS can tell when you've violated the Parameter Count Rule, but its comments about linear relationships among parameter estimates should be interpreted as merely a cry of pain. These symptoms can appear even when the parameters are identifiable, if maximum likelihood encounters numerical difficulties in the search. The problem could be caused by sample variances that are extremely different (resolved by re-scaling in the cars example below), or even by a bad starting value. The moral of the story is that you need to verify identifiability before fitting any structural equation model. This way, if there are numerical problems at least you can be sure that they re not caused by lack of identifiability.

   

• The Model: This model fails the Parameter Count Rule. The parameters are all identifiable where β₁ = β₂ = 0.

  

  For any ψ₁ and ψ₂, the covariance matrix is the same for all points on the circle defined by β₁² + β₂² = σ₁₂, so the sum of squared estimated regression coefficients should be σ₁₂-hat=0.96515, give or take the imprecision of numerical search.

• Circle.sas
  • First fit a model with ψ₁ ≠ ψ₂. This fails the parameter count rule, but there are no error message. There some Warnings and Notes in the log file and a couple of Notes in the results file file.
  • Get beta1-hat = 0.3417 and beta1-hat2 = 0.9211, yielding 0.3417^2 + 0.9211^2 = 0.9651841. Perfect. Note chisquare=0, df=-1
  • Make ψ₁ = ψ₂, passing the parameter count rule, but it no longer fits prefectly. Now have beta1-hat = 0.46203 and beta2-hat = 0.86700. Let's see ... 0.46203^2 + 0.86700^2 = 0.9651607, almost exactly. Note chisquare = 4.2609, df=0. The reproduced covariance matrix has variances equal, as it should.
  • Back to ψ₁ ≠ ψ₂, start at a very different place on the circle. sqrt(0.96515) = 0.9824205, so start at β₁ = -0.9824205, β₂=0. It shouldn't move. Oh yes, the other parameters. Also start at ψ₁ = 1.72246 - 0.96515 = 0.75731 , ψ₂ = 2.16043 - 0.96515 = 1.19528. Good, it did not move.
  • Y₃ and Y₄ were generated with true β₁ = β₂ = 0, identifiable at the true parameter value. Nasty symptoms but good estimates even though we have "significance." Note β₁² + β₂²  cannot match the negative sample covariance, but they get as close as possible, which happens to be exactly the true value of zero. This estimation problem is very unusual.

  /**************************** Circle.sas ****************************/
  title 'Try to fit a non-identified model';
  title2 'Jerry Brunner:  Student Number 999999999';
  
  data Bizarre;
       infile '/folders/myfolders/431s17/Circle.data.txt' firstobs=2 ;  /* Skipping the header */
       input id Y1-Y4;
  
  proc calis pshort nostand vardef=n pcorr;
  	 title3 'True beta1 = 0.7071068, beta2 = -0.7071068, psi1 = psi2 = 1';
  	 title4 'With psi1 neq psi2, fails parameter count rule';
       var Y1 Y2;  /* Declare observed variables */
       lineqs 
          /* Latent variables must begin with F for Factor.
             Error terms must begin with e or d (for disturbance) */
          Y1 = beta1*F1 + beta2*F2 + epsilon1,
          Y2 = beta1*F1 + beta2*F2 + epsilon2;
       variance                   /* Declare variance parameters. */
          epsilon1 = psi1, epsilon2 = psi2,
          F1 = 1, F2 = 1;
       cov
          F1 F2 = 0;
       /* Other unmentioned covariances are assumed zero. */
       /* If no means or intercepts are given, model is assumed to
          be in centered form. Unmentioned means and intercepts are 
          re-parameterized and disappear from the likelihood. */
  
  proc calis pshort nostand vardef=n pcorr;
  	 title3 'True beta1 = 0.7071068, beta2 = -0.7071068, psi1 = psi2 = 1';
  	 title4 'Passes parameter count rule with psi1=psi1=psi';
       var Y1 Y2;  /* Declare observed variables */
       lineqs 
          /* Latent variables must begin with F for Factor.
             Error terms must begin with e or d (for disturbance) */
          Y1 = beta1*F1 + beta2*F2 + epsilon1,
          Y2 = beta1*F1 + beta2*F2 + epsilon2;
       variance                   /* Declare variance parameters. */
          epsilon1 = psi, epsilon2 = psi,
          F1 = 1, F2 = 1;
       cov
          F1 F2 = 0;
  
  proc calis pshort nostand vardef=n pcorr;
  	 title3 'True beta1 = 0.7071068, beta2 = -0.7071068, psi1 = psi2 = 1';
  	 title4 'Psi1 neq psi2 again, start at beta1 = -0.9824205, beta2=0';
       var Y1 Y2;  /* Declare observed variables */
       lineqs 
          /* Latent variables must begin with F for Factor.
             Error terms must begin with e or d (for disturbance) */
          Y1 = beta1(-0.9824205)*F1 + beta2(0)*F2 + epsilon1,
          Y2 = beta1(-0.9824205)*F1 + beta2(0)*F2 + epsilon2;
       variance                   /* Declare variance parameters. */
          epsilon1 = psi1(0.75731), epsilon2 = psi2(1.19528),
          F1 = 1, F2 = 1;
       cov
          F1 F2 = 0;
  
  proc calis pshort nostand vardef=n pcorr;
  	 title3 'True beta1 = beta2 = 0, psi1 = psi2 = 1';
  	 title4 'Fails parameter count rule';
       var Y3 Y4;  /* Declare observed variables */
       lineqs 
          /* Latent variables must begin with F for Factor.
             Error terms must begin with e or d (for disturbance) */
          Y3 = beta1*F1 + beta2*F2 + epsilon1,
          Y4 = beta1*F1 + beta2*F2 + epsilon2;
       variance                   /* Declare variance parameters. */
          epsilon1 = psi1, epsilon2 = psi2,
          F1 = 1, F2 = 1;
       cov
          F1 F2 = 0;
  
  

  Results

• CarCalisReg.sas: Surface regression on the cars data with proc calis. We know this model is saturated and all the parameters are identifiable, but there are numerical problems and the symptoms resemble those in Circle.sas. The problems are resolved by re-scaling.

  title 'Metric Cars Data: Fit a regression model with proc calis';
  title2 'Jerry Brunner:  Student Number 999999999';
  
  /* Numerical problems due to differneces in scale. */
  
  data auto;
       infile '/folders/myfolders/431s17/mcars4.data' firstobs=2 ;  /* Skipping the header */
       input id country $ lper100k weight length;
  
  ods graphics off; /* Suppress regression plots */
  proc reg;
       title3 'Proc reg for comparison';     	 
       model lper100k = weight length;
       
  proc calis pshort nostand vardef=n pcorr;
  	 title3 'Surface regression with proc calis';
       var lper100k weight length;  /* Declare observed variables */
       lineqs 
          lper100k = beta0*Intercept + beta1*weight + beta2*length + epsilon;
      mean                       /* Declare non-zero mean parameters. */
          weight = mu1, length = mu2;
       variance                   /* Declare variance parameters. */
          weight = phi11,
          length = phi22,
          epsilon = psi;
       cov                        /* Declare non-zero covariance parameters. */
          weight length = phi12;  
   
   data auto2;
        set auto; /* Now auto2=auto */
        weight = weight/100; /* Re-scale so weight is in hundreds of kg.  */
        
  proc calis pshort nostand vardef=n pcorr;
  	 title3 'Weight re-scaled';
       var lper100k weight length;  /* Declare observed variables */
       lineqs 
          lper100k = beta0*Intercept + beta1*weight + beta2*length + epsilon;
      mean                       /* Declare non-zero mean parameters. */
          weight = mu1, length = mu2;
       variance                   /* Declare variance parameters. */
          weight = phi11,
          length = phi22,
          epsilon = psi;
       cov                        /* Declare non-zero covariance parameters. */
          weight length = phi12;  
  
  

  Results